Next Previous Contents

## 11. Control commands

Here's a list of all control commands and a description, what they do:

## 11.1 `.A16`

Valid only in 65816 mode. Switch the accumulator to 16 bit.

Note: This command will not emit any code, it will tell the assembler to create 16 bit operands for immediate accumulator addressing mode.

See also: `.SMART`

## 11.2 `.A8`

Valid only in 65816 mode. Switch the accumulator to 8 bit.

Note: This command will not emit any code, it will tell the assembler to create 8 bit operands for immediate accu addressing mode.

See also: `.SMART`

## 11.3 `.ADDR`

Define word sized data. In 6502 mode, this is an alias for `.WORD` and may be used for better readability if the data words are address values. In 65816 mode, the address is forced to be 16 bit wide to fit into the current segment. See also `.FARADDR`. The command must be followed by a sequence of (not necessarily constant) expressions.

Example:

> `

>             .addr   $0D00, $AF13, _Clear

> `

See: `.FARADDR`, `.WORD`

## 11.4 `.ALIGN`

Align data to a given boundary. The command expects a constant integer argument that must be a power of two, plus an optional second argument in byte range. If there is a second argument, it is used as fill value, otherwise the value defined in the linker configuration file is used (the default for this value is zero).

Since alignment depends on the base address of the module, you must give the same (or a greater) alignment for the segment when linking. The linker will give you a warning, if you don't do that.

Example:

> `

>             .align  256

> `

## 11.5 `.ASCIIZ`

Define a string with a trailing zero.

Example:

> `

>             Msg:    .asciiz "Hello world"

> `

This will put the string "Hello world" followed by a binary zero into the current segment. There may be more strings separated by commas, but the binary zero is only appended once (after the last one).

## 11.6 `.ASSERT`

Add an assertion. The command is followed by an expression, an action specifier, and an optional message that is output in case the assertion fails. If no message was given, the string "Assertion failed" is used. The action specifier may be one of `warning` or `error`. The assertion is evaluated by the assembler if possible, and also passed to the linker in the object file (if one is generated). The linker will then evaluate the expression when segment placement has been done.

Example:

> `

>             .assert         * = $8000, error, "Code not at $8000"

> `

The example assertion will check that the current location is at $8000, when the output file is written, and abort with an error if this is not the case. More complex expressions are possible. The action specifier `warning` outputs a warning, while the `error` specifier outputs an error message. In the latter case, generation of the output file is suppressed in both the assembler and linker.

## 11.7 `.AUTOIMPORT`

Is followed by a plus or a minus character. When switched on (using a +), undefined symbols are automatically marked as import instead of giving errors. When switched off (which is the default so this does not make much sense), this does not happen and an error message is displayed. The state of the autoimport flag is evaluated when the complete source was translated, before outputting actual code, so it is not possible to switch this feature on or off for separate sections of code. The last setting is used for all symbols.

You should probably not use this switch because it delays error messages about undefined symbols until the link stage. The cc65 compiler (which is supposed to produce correct assembler code in all circumstances, something which is not true for most assembler programmers) will insert this command to avoid importing each and every routine from the runtime library.

Example:

> `

>             .autoimport     +       ; Switch on auto import

> `

## 11.8 `.BANKBYTES`

Define byte sized data by extracting only the bank byte (that is, bits 16-23) from each expression. This is equivalent to `.BYTE` with the operator '^' prepended to each expression in its list.

Example:

> `

>             .define MyTable TableItem0, TableItem1, TableItem2, TableItem3

>             TableLookupLo:   .lobytes   MyTable
>             TableLookupHi:   .hibytes   MyTable
>             TableLookupBank: .bankbytes MyTable

> `

which is equivalent to

> `

>             TableLookupLo:   .byte <TableItem0, <TableItem1, <TableItem2, <TableItem3
>             TableLookupHi:   .byte >TableItem0, >TableItem1, >TableItem2, >TableItem3
>             TableLookupBank: .byte ^TableItem0, ^TableItem1, ^TableItem2, ^TableItem3

> `

See also: `.BYTE`, `.HIBYTES`, `.LOBYTES`

## 11.9 `.BSS`

Switch to the BSS segment. The name of the BSS segment is always "BSS", so this is a shortcut for

> `

>             .segment  "BSS"

> `

See also the `.SEGMENT` command.

## 11.10 `.BYT, .BYTE`

Define byte sized data. Must be followed by a sequence of (byte ranged) expressions or strings.

Example:

> `

>             .byte   "Hello "
>             .byt    "world", $0D, $00

> `

## 11.11 `.CASE`

Switch on or off case sensitivity on identifiers. The default is off (that is, identifiers are case sensitive), but may be changed by the -i switch on the command line. The command must be followed by a '+' or '-' character to switch the option on or off respectively.

Example:

> `

>             .case   -               ; Identifiers are not case sensitive

> `

## 11.12 `.CHARMAP`

Apply a custom mapping for characters. The command is followed by two numbers in the range 1..255. The first one is the index of the source character, the second one is the mapping. The mapping applies to all character and string constants when they generate output, and overrides a mapping table specified with the `-t` command line switch.

Example:

> `

>             .charmap        $41, $61        ; Map 'A' to 'a'

> `

## 11.13 `.CODE`

Switch to the CODE segment. The name of the CODE segment is always "CODE", so this is a shortcut for

> `

>             .segment  "CODE"

> `

See also the `.SEGMENT` command.

## 11.14 `.CONDES`

Export a symbol and mark it in a special way. The linker is able to build tables of all such symbols. This may be used to automatically create a list of functions needed to initialize linked library modules.

Note: The linker has a feature to build a table of marked routines, but it is your code that must call these routines, so just declaring a symbol with `.CONDES` does nothing by itself.

All symbols are exported as an absolute (16 bit) symbol. You don't need to use an additional `.EXPORT` statement, this is implied by `.CONDES`.

`.CONDES` is followed by the type, which may be `constructor`, `destructor` or a numeric value between 0 and 6 (where 0 is the same as specifying `constructor` and 1 is equal to specifying `destructor`). The `.CONSTRUCTOR`, `.DESTRUCTOR` and `.INTERRUPTOR` commands are actually shortcuts for `.CONDES` with a type of `constructor` resp. `destructor` or `interruptor`.

After the type, an optional priority may be specified. Higher numeric values mean higher priority. If no priority is given, the default priority of 7 is used. Be careful when assigning priorities to your own module constructors so they won't interfere with the ones in the cc65 library.

Example:

> `

>             .condes         ModuleInit, constructor
>             .condes         ModInit, 0, 16

> `

See the `.CONSTRUCTOR`, `.DESTRUCTOR` and `.INTERRUPTOR` commands and the separate section Module constructors/destructors explaining the feature in more detail.

## 11.15 `.CONSTRUCTOR`

Export a symbol and mark it as a module constructor. This may be used together with the linker to build a table of constructor subroutines that are called by the startup code.

Note: The linker has a feature to build a table of marked routines, but it is your code that must call these routines, so just declaring a symbol as constructor does nothing by itself.

A constructor is always exported as an absolute (16 bit) symbol. You don't need to use an additional `.export` statement, this is implied by `.constructor`. It may have an optional priority that is separated by a comma. Higher numeric values mean a higher priority. If no priority is given, the default priority of 7 is used. Be careful when assigning priorities to your own module constructors so they won't interfere with the ones in the cc65 library.

Example:

> `

>             .constructor    ModuleInit
>             .constructor    ModInit, 16

> `

See the `.CONDES` and `.DESTRUCTOR` commands and the separate section Module constructors/destructors explaining the feature in more detail.

## 11.16 `.DATA`

Switch to the DATA segment. The name of the DATA segment is always "DATA", so this is a shortcut for

> `

>             .segment  "DATA"

> `

See also the `.SEGMENT` command.

## 11.17 `.DBYT`

Define word sized data with the hi and lo bytes swapped (use `.WORD` to create word sized data in native 65XX format). Must be followed by a sequence of (word ranged) expressions.

Example:

> `

>             .dbyt   $1234, $4512

> `

This will emit the bytes

> `

>             $12 $34 $45 $12

> `

into the current segment in that order.

## 11.18 `.DEBUGINFO`

Switch on or off debug info generation. The default is off (that is, the object file will not contain debug infos), but may be changed by the -g switch on the command line. The command must be followed by a '+' or '-' character to switch the option on or off respectively.

Example:

> `

>             .debuginfo      +       ; Generate debug info

> `

## 11.19 `.DEFINE`

Start a define style macro definition. The command is followed by an identifier (the macro name) and optionally by a list of formal arguments in braces. See section Macros.

## 11.20 `.DEF, .DEFINED`

Builtin function. The function expects an identifier as argument in braces. The argument is evaluated, and the function yields "true" if the identifier is a symbol that is already defined somewhere in the source file up to the current position. Otherwise the function yields false. As an example, the `.IFDEF` statement may be replaced by

> `

>             .if     .defined(a)

> `

## 11.21 `.DESTRUCTOR`

Export a symbol and mark it as a module destructor. This may be used together with the linker to build a table of destructor subroutines that are called by the startup code.

Note: The linker has a feature to build a table of marked routines, but it is your code that must call these routines, so just declaring a symbol as constructor does nothing by itself.

A destructor is always exported as an absolute (16 bit) symbol. You don't need to use an additional `.export` statement, this is implied by `.destructor`. It may have an optional priority that is separated by a comma. Higher numerical values mean a higher priority. If no priority is given, the default priority of 7 is used. Be careful when assigning priorities to your own module destructors so they won't interfere with the ones in the cc65 library.

Example:

> `

>             .destructor     ModuleDone
>             .destructor     ModDone, 16

> `

See the `.CONDES` and `.CONSTRUCTOR` commands and the separate section Module constructors/destructors explaining the feature in more detail.

## 11.22 `.DWORD`

Define dword sized data (4 bytes) Must be followed by a sequence of expressions.

Example:

> `

>             .dword  $12344512, $12FA489

> `

## 11.23 `.ELSE`

Conditional assembly: Reverse the current condition.

## 11.24 `.ELSEIF`

Conditional assembly: Reverse current condition and test a new one.

## 11.25 `.END`

Forced end of assembly. Assembly stops at this point, even if the command is read from an include file.

## 11.26 `.ENDENUM`

End a `.ENUM` declaration.

## 11.27 `.ENDIF`

Conditional assembly: Close a `.IF...` or `.ELSE` branch.

## 11.28 `.ENDMAC, .ENDMACRO`

End of macro definition (see section Macros).

## 11.29 `.ENDPROC`

End of local lexical level (see `.PROC`).

## 11.30 `.ENDREP, .ENDREPEAT`

End a `.REPEAT` block.

## 11.31 `.ENDSCOPE`

End of local lexical level (see `.SCOPE`).

## 11.32 `.ENDSTRUCT`

Ends a struct definition. See the `.STRUCT` command and the separate section named "Structs and unions".

## 11.33 `.ENUM`

Start an enumeration. This directive is very similar to the C `enum` keyword. If a name is given, a new scope is created for the enumeration, otherwise the enumeration members are placed in the enclosing scope.

In the enumeration body, symbols are declared. The first symbol has a value of zero, and each following symbol will get the value of the preceding plus one. This behaviour may be overridden by an explicit assignment. Two symbols may have the same value.

Example:

> `

>             .enum   errorcodes
>                     no_error
>                     file_error
>                     parse_error
>             .endenum

> `

Above example will create a new scope named `errorcodes` with three symbols in it that get the values 0, 1 and 2 respectively. Another way to write this would have been:

> `

>             .scope  errorcodes
>                     no_error        = 0
>                     file_error      = 1
>                     parse_error     = 2
>             .endscope

> `

Please note that explicit scoping must be used to access the identifiers:

> `

>             .word   errorcodes::no_error

> `

A more complex example:

> `

>             .enum
>                     EUNKNOWN        = -1
>                     EOK
>                     EFILE
>                     EBUSY
>                     EAGAIN
>                     EWOULDBLOCK     = EAGAIN
>             .endenum

> `

In this example, the enumeration does not have a name, which means that the members will be visible in the enclosing scope and can be used in this scope without explicit scoping. The first member (`EUNKNOWN`) has the value -1. The value for the following members is incremented by one, so `EOK` would be zero and so on. `EWOULDBLOCK` is an alias for `EGAIN`, so it has an override for the value using an already defined symbol.

## 11.34 `.ERROR`

Force an assembly error. The assembler will output an error message preceded by "User error" and will not produce an object file.

This command may be used to check for initial conditions that must be set before assembling a source file.

Example:

> `

>             .if     foo = 1
>             ...
>             .elseif bar = 1
>             ...
>             .else
>             .error  "Must define foo or bar!"
>             .endif

> `

See also the `.WARNING` and `.OUT` directives.

## 11.35 `.EXITMAC, .EXITMACRO`

Abort a macro expansion immediately. This command is often useful in recursive macros. See separate section Macros.

## 11.36 `.EXPORT`

Make symbols accessible from other modules. Must be followed by a comma separated list of symbols to export, with each one optionally followed by an address specification and (also optional) an assignment. Using an additional assignment in the export statement allows to define and export a symbol in one statement. The default is to export the symbol with the address size it actually has. The assembler will issue a warning, if the symbol is exported with an address size smaller than the actual address size.

Examples:

> `

>             .export foo
>             .export bar: far
>             .export foobar: far = foo * bar
>             .export baz := foobar, zap: far = baz - bar

> `

As with constant definitions, using `:=` instead of `=` marks the symbols as a label.

See: `.EXPORTZP`

## 11.37 `.EXPORTZP`

Make symbols accessible from other modules. Must be followed by a comma separated list of symbols to export. The exported symbols are explicitly marked as zero page symbols. An assignment may be included in the `.EXPORTZP` statement. This allows to define and export a symbol in one statement.

Examples:

> `

>             .exportzp  foo, bar
>             .exportzp  baz := $02

> `

See: `.EXPORT`

## 11.38 `.FARADDR`

Define far (24 bit) address data. The command must be followed by a sequence of (not necessarily constant) expressions.

Example:

> `

>             .faraddr        DrawCircle, DrawRectangle, DrawHexagon

> `

See: `.ADDR`

## 11.39 `.FEATURE`

This directive may be used to enable one or more compatibility features of the assembler. While the use of `.FEATURE` should be avoided when possible, it may be useful when porting sources written for other assemblers. There is no way to switch a feature off, once you have enabled it, so using

> `

>             .FEATURE        xxx

> `

will enable the feature until end of assembly is reached.

The following features are available:

`at_in_identifiers`

  Accept the at character (`@') as a valid character in identifiers. The at character is not allowed to start an identifier, even with this feature enabled.

`c_comments`

  Allow C like comments using `/*` and `*/` as left and right comment terminators. Note that C comments may not be nested. There's also a pitfall when using C like comments: All statements must be terminated by "end-of-line". Using C like comments, it is possible to hide the newline, which results in error messages. See the following non working example:

  > `

  >             lda     #$00  /* This comment hides the newline
  >     */      sta     $82

  > `

`dollar_in_identifiers`

  Accept the dollar sign (`$') as a valid character in identifiers. The dollar character is not allowed to start an identifier, even with this feature enabled.

`dollar_is_pc`

  The dollar sign may be used as an alias for the star (`*'), which gives the value of the current PC in expressions. Note: Assignment to the pseudo variable is not allowed.

`labels_without_colons`

  Allow labels without a trailing colon. These labels are only accepted, if they start at the beginning of a line (no leading white space).

`leading_dot_in_identifiers`

  Accept the dot (`.') as the first character of an identifier. This may be used for example to create macro names that start with a dot emulating control directives of other assemblers. Note however, that none of the reserved keywords built into the assembler, that starts with a dot, may be overridden. When using this feature, you may also get into trouble if later versions of the assembler define new keywords starting with a dot.

`loose_char_term`

  Accept single quotes as well as double quotes as terminators for char constants.

`loose_string_term`

  Accept single quotes as well as double quotes as terminators for string constants.

`missing_char_term`

  Accept single quoted character constants where the terminating quote is missing.

  > `

  >             lda     #'a

  > `

  Note: This does not work in conjunction with `.FEATURE loose_string_term`, since in this case the input would be ambiguous.
`org_per_seg`

  This feature makes relocatable/absolute mode local to the current segment. Using `.ORG` when `org_per_seg` is in effect will only enable absolute mode for the current segment. Dito for `.RELOC`.

`pc_assignment`

  Allow assignments to the PC symbol (`*' or `$' if `dollar_is_pc` is enabled). Such an assignment is handled identical to the `.ORG` command (which is usually not needed, so just removing the lines with the assignments may also be an option when porting code written for older assemblers).

`ubiquitous_idents`

  Allow the use of instructions names as names for macros and symbols. This makes it possible to "overload" instructions by defining a macro with the same name. This does also make it possible to introduce hard to find errors in your code, so be careful!

It is also possible to specify features on the command line using the `--feature` command line option. This is useful when translating sources written for older assemblers, when you don't want to change the source code.

As an example, to translate sources written for Andre Fachats xa65 assembler, the features

            labels_without_colons, pc_assignment, loose_char_term

may be helpful. They do not make ca65 completely compatible, so you may not be able to translate the sources without changes, even when enabling these features. However, I have found several sources that translate without problems when enabling these features on the command line.

## 11.40 `.FILEOPT, .FOPT`

Insert an option string into the object file. There are two forms of this command, one specifies the option by a keyword, the second specifies it as a number. Since usage of the second one needs knowledge of the internal encoding, its use is not recommended and I will only describe the first form here.

The command is followed by one of the keywords

> `

>             author
>             comment
>             compiler

> `

a comma and a string. The option is written into the object file together with the string value. This is currently unidirectional and there is no way to actually use these options once they are in the object file.

Examples:

> `

>             .fileopt        comment, "Code stolen from my brother"
>             .fileopt        compiler, "BASIC 2.0"
>             .fopt           author, "J. R. User"

> `

## 11.41 `.FORCEIMPORT`

Import an absolute symbol from another module. The command is followed by a comma separated list of symbols to import. The command is similar to `.IMPORT`, but the import reference is always written to the generated object file, even if the symbol is never referenced (`.IMPORT` will not generate import references for unused symbols).

Example:

> `

>             .forceimport    needthisone, needthistoo

> `

See: `.IMPORT`

## 11.42 `.GLOBAL`

Declare symbols as global. Must be followed by a comma separated list of symbols to declare. Symbols from the list, that are defined somewhere in the source, are exported, all others are imported. Additional `.IMPORT` or `.EXPORT` commands for the same symbol are allowed.

Example:

> `

>             .global foo, bar

> `

## 11.43 `.GLOBALZP`

Declare symbols as global. Must be followed by a comma separated list of symbols to declare. Symbols from the list, that are defined somewhere in the source, are exported, all others are imported. Additional `.IMPORTZP` or `.EXPORTZP` commands for the same symbol are allowed. The symbols in the list are explicitly marked as zero page symbols.

Example:

> `

>             .globalzp foo, bar

> `

## 11.44 `.HIBYTES`

Define byte sized data by extracting only the high byte (that is, bits 8-15) from each expression. This is equivalent to `.BYTE` with the operator '>' prepended to each expression in its list.

Example:

> `

>             .lobytes         $1234, $2345, $3456, $4567
>             .hibytes         $fedc, $edcb, $dcba, $cba9

> `

which is equivalent to

> `

>             .byte            $34, $45, $56, $67
>             .byte            $fe, $ed, $dc, $cb

> `

Example:

> `

>             .define MyTable TableItem0, TableItem1, TableItem2, TableItem3

>             TableLookupLo:   .lobytes MyTable
>             TableLookupHi:   .hibytes MyTable

> `

which is equivalent to

> `

>             TableLookupLo:   .byte <TableItem0, <TableItem1, <TableItem2, <TableItem3
>             TableLookupHi:   .byte >TableItem0, >TableItem1, >TableItem2, >TableItem3

> `

See also: `.BYTE`, `.LOBYTES`, `.BANKBYTES`

## 11.45 `.I16`

Valid only in 65816 mode. Switch the index registers to 16 bit.

Note: This command will not emit any code, it will tell the assembler to create 16 bit operands for immediate operands.

See also the `.I8` and `.SMART` commands.

## 11.46 `.I8`

Valid only in 65816 mode. Switch the index registers to 8 bit.

Note: This command will not emit any code, it will tell the assembler to create 8 bit operands for immediate operands.

See also the `.I16` and `.SMART` commands.

## 11.47 `.IF`

Conditional assembly: Evaluate an expression and switch assembler output on or off depending on the expression. The expression must be a constant expression, that is, all operands must be defined.

A expression value of zero evaluates to FALSE, any other value evaluates to TRUE.

## 11.48 `.IFBLANK`

Conditional assembly: Check if there are any remaining tokens in this line, and evaluate to FALSE if this is the case, and to TRUE otherwise. If the condition is not true, further lines are not assembled until an `.ESLE`, `.ELSEIF` or `.ENDIF` directive.

This command is often used to check if a macro parameter was given. Since an empty macro parameter will evaluate to nothing, the condition will evaluate to FALSE if an empty parameter was given.

Example:

> `

>             .macro     arg1, arg2
>             .ifblank   arg2
>                        lda     #arg1
>             .else
>                        lda     #arg2
>             .endif
>             .endmacro

> `

See also: `.BLANK`

## 11.49 `.IFCONST`

Conditional assembly: Evaluate an expression and switch assembler output on or off depending on the constness of the expression.

A const expression evaluates to to TRUE, a non const expression (one containing an imported or currently undefined symbol) evaluates to FALSE.

See also: `.CONST`

## 11.50 `.IFDEF`

Conditional assembly: Check if a symbol is defined. Must be followed by a symbol name. The condition is true if the the given symbol is already defined, and false otherwise.

See also: `.DEFINED`

## 11.51 `.IFNBLANK`

Conditional assembly: Check if there are any remaining tokens in this line, and evaluate to TRUE if this is the case, and to FALSE otherwise. If the condition is not true, further lines are not assembled until an `.ELSE`, `.ELSEIF` or `.ENDIF` directive.

This command is often used to check if a macro parameter was given. Since an empty macro parameter will evaluate to nothing, the condition will evaluate to FALSE if an empty parameter was given.

Example:

> `

>             .macro     arg1, arg2
>                        lda     #arg1
>             .ifnblank  arg2
>                        lda     #arg2
>             .endif
>             .endmacro

> `

See also: `.BLANK`

## 11.52 `.IFNDEF`

Conditional assembly: Check if a symbol is defined. Must be followed by a symbol name. The condition is true if the the given symbol is not defined, and false otherwise.

See also: `.DEFINED`

## 11.53 `.IFNREF`

Conditional assembly: Check if a symbol is referenced. Must be followed by a symbol name. The condition is true if if the the given symbol was not referenced before, and false otherwise.

See also: `.REFERENCED`

## 11.54 `.IFP02`

Conditional assembly: Check if the assembler is currently in 6502 mode (see `.P02` command).

## 11.55 `.IFP816`

Conditional assembly: Check if the assembler is currently in 65816 mode (see `.P816` command).

## 11.56 `.IFPC02`

Conditional assembly: Check if the assembler is currently in 65C02 mode (see `.PC02` command).

## 11.57 `.IFPSC02`

Conditional assembly: Check if the assembler is currently in 65SC02 mode (see `.PSC02` command).

## 11.58 `.IFREF`

Conditional assembly: Check if a symbol is referenced. Must be followed by a symbol name. The condition is true if if the the given symbol was referenced before, and false otherwise.

This command may be used to build subroutine libraries in include files (you may use separate object modules for this purpose too).

Example:

> `

>             .ifref  ToHex                   ; If someone used this subroutine
>             ToHex:  tay                     ; Define subroutine
>                     lda     HexTab,y
>                     rts
>             .endif

> `

See also: `.REFERENCED`

## 11.59 `.IMPORT`

Import a symbol from another module. The command is followed by a comma separated list of symbols to import, with each one optionally followed by an address specification.

Example:

> `

>             .import foo
>             .import bar: zeropage

> `

See: `.IMPORTZP`

## 11.60 `.IMPORTZP`

Import a symbol from another module. The command is followed by a comma separated list of symbols to import. The symbols are explicitly imported as zero page symbols (that is, symbols with values in byte range).

Example:

> `

>             .importzp       foo, bar

> `

See: `.IMPORT`

## 11.61 `.INCBIN`

Include a file as binary data. The command expects a string argument that is the name of a file to include literally in the current segment. In addition to that, a start offset and a size value may be specified, separated by commas. If no size is specified, all of the file from the start offset to end-of-file is used. If no start position is specified either, zero is assumed (which means that the whole file is inserted).

Example:

> `

>             ; Include whole file
>             .incbin         "sprites.dat"

>             ; Include file starting at offset 256
>             .incbin         "music.dat", $100

>             ; Read 100 bytes starting at offset 200
>             .incbin         "graphics.dat", 200, 100

> `

## 11.62 `.INCLUDE`

Include another file. Include files may be nested up to a depth of 16.

Example:

> `

>             .include        "subs.inc"

> `

## 11.63 `.INTERRUPTOR`

Export a symbol and mark it as an interruptor. This may be used together with the linker to build a table of interruptor subroutines that are called in an interrupt.

Note: The linker has a feature to build a table of marked routines, but it is your code that must call these routines, so just declaring a symbol as interruptor does nothing by itself.

An interruptor is always exported as an absolute (16 bit) symbol. You don't need to use an additional `.export` statement, this is implied by `.interruptor`. It may have an optional priority that is separated by a comma. Higher numeric values mean a higher priority. If no priority is given, the default priority of 7 is used. Be careful when assigning priorities to your own module constructors so they won't interfere with the ones in the cc65 library.

Example:

> `

>             .interruptor    IrqHandler
>             .interruptor    Handler, 16

> `

See the `.CONDES` command and the separate section Module constructors/destructors explaining the feature in more detail.

## 11.64 `.LINECONT`

Switch on or off line continuations using the backslash character before a newline. The option is off by default. Note: Line continuations do not work in a comment. A backslash at the end of a comment is treated as part of the comment and does not trigger line continuation. The command must be followed by a '+' or '-' character to switch the option on or off respectively.

Example:

> `

>             .linecont       +               ; Allow line continuations

>             lda     \
>                     #$20                    ; This is legal now

> `

## 11.65 `.LIST`

Enable output to the listing. The command must be followed by a boolean switch ("on", "off", "+" or "-") and will enable or disable listing output. The option has no effect if the listing is not enabled by the command line switch -l. If -l is used, an internal counter is set to 1. Lines are output to the listing file, if the counter is greater than zero, and suppressed if the counter is zero. Each use of `.LIST` will increment or decrement the counter.

Example:

> `

>             .list   on              ; Enable listing output

> `

## 11.66 `.LISTBYTES`

Set, how many bytes are shown in the listing for one source line. The default is 12, so the listing will show only the first 12 bytes for any source line that generates more than 12 bytes of code or data. The directive needs an argument, which is either "unlimited", or an integer constant in the range 4..255.

Examples:

> `

>             .listbytes      unlimited       ; List all bytes
>             .listbytes      12              ; List the first 12 bytes
>             .incbin         "data.bin"      ; Include large binary file

> `

## 11.67 `.LOBYTES`

Define byte sized data by extracting only the low byte (that is, bits 0-7) from each expression. This is equivalent to `.BYTE` with the operator '<' prepended to each expression in its list.

Example:

> `

>             .lobytes         $1234, $2345, $3456, $4567
>             .hibytes         $fedc, $edcb, $dcba, $cba9

> `

which is equivalent to

> `

>             .byte            $34, $45, $56, $67
>             .byte            $fe, $ed, $dc, $cb

> `

Example:

> `

>             .define MyTable TableItem0, TableItem1, TableItem2, TableItem3

>             TableLookupLo:   .lobytes MyTable
>             TableLookupHi:   .hibytes MyTable

> `

which is equivalent to

> `

>             TableLookupLo:   .byte <TableItem0, <TableItem1, <TableItem2, <TableItem3
>             TableLookupHi:   .byte >TableItem0, >TableItem1, >TableItem2, >TableItem3

> `

See also: `.BYTE`, `.HIBYTES`, `.BANKBYTES`

## 11.68 `.LOCAL`

This command may only be used inside a macro definition. It declares a list of identifiers as local to the macro expansion.

A problem when using macros are labels: Since they don't change their name, you get a "duplicate symbol" error if the macro is expanded the second time. Labels declared with `.LOCAL` have their name mapped to an internal unique name (`___ABCD__`) with each macro invocation.

Some other assemblers start a new lexical block inside a macro expansion. This has some drawbacks however, since that will not allow any symbol to be visible outside a macro, a feature that is sometimes useful. The `.LOCAL` command is in my eyes a better way to address the problem.

You get an error when using `.LOCAL` outside a macro.

## 11.69 `.LOCALCHAR`

Defines the character that start "cheap" local labels. You may use one of '@' and '?' as start character. The default is '@'.

Cheap local labels are labels that are visible only between two non cheap labels. This way you can reuse identifiers like "`loop`" without using explicit lexical nesting.

Example:

> `

>             .localchar      '?'

>             Clear:  lda     #$00            ; Global label
>             ?Loop:  sta     Mem,y           ; Local label
>                     dey
>                     bne     ?Loop           ; Ok
>                     rts
>             Sub:    ...                     ; New global label
>                     bne     ?Loop           ; ERROR: Unknown identifier!

> `

## 11.70 `.MACPACK`

Insert a predefined macro package. The command is followed by an identifier specifying the macro package to insert. Available macro packages are:

> `

>             atari           Defines the scrcode macro.
>             cbm             Defines the scrcode macro.
>             cpu             Defines constants for the .CPU variable.
>             generic         Defines generic macros like add and sub.
>             longbranch      Defines conditional long jump macros.

> `

Including a macro package twice, or including a macro package that redefines already existing macros will lead to an error.

Example:

> `

>             .macpack        longbranch      ; Include macro package

>                     cmp     #$20            ; Set condition codes
>                     jne     Label           ; Jump long on condition

> `

Macro packages are explained in more detail in section Macro packages.

## 11.71 `.MAC, .MACRO`

Start a classic macro definition. The command is followed by an identifier (the macro name) and optionally by a comma separated list of identifiers that are macro parameters.

See section Macros.

## 11.72 `.ORG`

Start a section of absolute code. The command is followed by a constant expression that gives the new PC counter location for which the code is assembled. Use `.RELOC` to switch back to relocatable code.

By default, absolute/relocatable mode is global (valid even when switching segments). Using `.FEATURE org_per_seg` it can be made segment local.

Please note that you do not need `.ORG` in most cases. Placing code at a specific address is the job of the linker, not the assembler, so there is usually no reason to assemble code to a specific address.

Example:

> `

>             .org    $7FF            ; Emit code starting at $7FF

> `

## 11.73 `.OUT`

Output a string to the console without producing an error. This command is similar to `.ERROR`, however, it does not force an assembler error that prevents the creation of an object file.

Example:

> `

>             .out    "This code was written by the codebuster(tm)"

> `

See also the `.WARNING` and `.ERROR` directives.

## 11.74 `.P02`

Enable the 6502 instruction set, disable 65SC02, 65C02 and 65816 instructions. This is the default if not overridden by the `--cpu` command line option.

See: `.PC02`, `.PSC02` and `.P816`

## 11.75 `.P816`

Enable the 65816 instruction set. This is a superset of the 65SC02 and 6502 instruction sets.

See: `.P02`, `.PSC02` and `.PC02`

## 11.76 `.PAGELEN, .PAGELENGTH`

Set the page length for the listing. Must be followed by an integer constant. The value may be "unlimited", or in the range 32 to 127. The statement has no effect if no listing is generated. The default value is -1 (unlimited) but may be overridden by the `--pagelength` command line option. Beware: Since ca65 is a one pass assembler, the listing is generated after assembly is complete, you cannot use multiple line lengths with one source. Instead, the value set with the last `.PAGELENGTH` is used.

Examples:

> `

>             .pagelength     66              ; Use 66 lines per listing page

>             .pagelength     unlimited       ; Unlimited page length

> `

## 11.77 `.PC02`

Enable the 65C02 instructions set. This instruction set includes all 6502 and 65SC02 instructions.

See: `.P02`, `.PSC02` and `.P816`

## 11.78 `.POPSEG`

Pop the last pushed segment from the stack, and set it.

This command will switch back to the segment that was last pushed onto the segment stack using the `.PUSHSEG` command, and remove this entry from the stack.

The assembler will print an error message if the segment stack is empty when this command is issued.

See: `.PUSHSEG`

## 11.79 `.PROC`

Start a nested lexical level with the given name and adds a symbol with this name to the enclosing scope. All new symbols from now on are in the local lexical level and are accessible from outside only via explicit scope specification. Symbols defined outside this local level may be accessed as long as their names are not used for new symbols inside the level. Symbols names in other lexical levels do not clash, so you may use the same names for identifiers. The lexical level ends when the `.ENDPROC` command is read. Lexical levels may be nested up to a depth of 16 (this is an artificial limit to protect against errors in the source).

Note: Macro names are always in the global level and in a separate name space. There is no special reason for this, it's just that I've never had any need for local macro definitions.

Example:

> `

>             .proc   Clear           ; Define Clear subroutine, start new level
>                     lda     #$00
>             L1:     sta     Mem,y   ; L1 is local and does not cause a
>                                     ; duplicate symbol error if used in other
>                                     ; places
>                     dey
>                     bne     L1      ; Reference local symbol
>                     rts
>             .endproc                ; Leave lexical level

> `

See: `.ENDPROC` and `.SCOPE`

## 11.80 `.PSC02`

Enable the 65SC02 instructions set. This instruction set includes all 6502 instructions.

See: `.P02`, `.PC02` and `.P816`

## 11.81 `.PUSHSEG`

Push the currently active segment onto a stack. The entries on the stack include the name of the segment and the segment type. The stack has a size of 16 entries.

`.PUSHSEG` allows together with `.POPSEG` to switch to another segment and to restore the old segment later, without even knowing the name and type of the current segment.

The assembler will print an error message if the segment stack is already full, when this command is issued.

See: `.POPSEG`

## 11.82 `.RELOC`

Switch back to relocatable mode. See the `.ORG` command.

## 11.83 `.REPEAT`

Repeat all commands between `.REPEAT` and `.ENDREPEAT` constant number of times. The command is followed by a constant expression that tells how many times the commands in the body should get repeated. Optionally, a comma and an identifier may be specified. If this identifier is found in the body of the repeat statement, it is replaced by the current repeat count (starting with zero for the first time the body is repeated).

`.REPEAT` statements may be nested. If you use the same repeat count identifier for a nested `.REPEAT` statement, the one from the inner level will be used, not the one from the outer level.

Example:

The following macro will emit a string that is "encrypted" in that all characters of the string are XORed by the value $55.

> `

>             .macro  Crypt   Arg
>                     .repeat .strlen(Arg), I
>                     .byte   .strat(Arg, I) ^ $55
>                     .endrep
>             .endmacro

> `

See: `.ENDREPEAT`

## 11.84 `.RES`

Reserve storage. The command is followed by one or two constant expressions. The first one is mandatory and defines, how many bytes of storage should be defined. The second, optional expression must by a constant byte value that will be used as value of the data. If there is no fill value given, the linker will use the value defined in the linker configuration file (default: zero).

Example:

> `

>             ; Reserve 12 bytes of memory with value $AA
>             .res    12, $AA

> `

## 11.85 `.RODATA`

Switch to the RODATA segment. The name of the RODATA segment is always "RODATA", so this is a shortcut for

> `

>             .segment  "RODATA"

> `

The RODATA segment is a segment that is used by the compiler for readonly data like string constants.

See also the `.SEGMENT` command.

## 11.86 `.SCOPE`

Start a nested lexical level with the given name. All new symbols from now on are in the local lexical level and are accessible from outside only via explicit scope specification. Symbols defined outside this local level may be accessed as long as their names are not used for new symbols inside the level. Symbols names in other lexical levels do not clash, so you may use the same names for identifiers. The lexical level ends when the `.ENDSCOPE` command is read. Lexical levels may be nested up to a depth of 16 (this is an artificial limit to protect against errors in the source).

Note: Macro names are always in the global level and in a separate name space. There is no special reason for this, it's just that I've never had any need for local macro definitions.

Example:

> `

>             .scope  Error                   ; Start new scope named Error
>                     None = 0                ; No error
>                     File = 1                ; File error
>                     Parse = 2               ; Parse error
>             .endscope                       ; Close lexical level

>                     ...
>                     lda #Error::File        ; Use symbol from scope Error

> `

See: `.ENDSCOPE` and `.PROC`

## 11.87 `.SEGMENT`

Switch to another segment. Code and data is always emitted into a segment, that is, a named section of data. The default segment is "CODE". There may be up to 254 different segments per object file (and up to 65534 per executable). There are shortcut commands for the most common segments ("CODE", "DATA" and "BSS").

The command is followed by a string containing the segment name (there are some constraints for the name - as a rule of thumb use only those segment names that would also be valid identifiers). There may also be an optional address size separated by a colon. See the section covering `address sizes` for more information.

The default address size for a segment depends on the memory model specified on the command line. The default is "absolute", which means that you don't have to use an address size modifier in most cases.

"absolute" means that the is a segment with 16 bit (absolute) addressing. That is, the segment will reside somewhere in core memory outside the zero page. "zeropage" (8 bit) means that the segment will be placed in the zero page and direct (short) addressing is possible for data in this segment.

Beware: Only labels in a segment with the zeropage attribute are marked as reachable by short addressing. The `*' (PC counter) operator will work as in other segments and will create absolute variable values.

Please note that a segment cannot have two different address sizes. A segment specified as zeropage cannot be declared as being absolute later.

Examples:

> `

>             .segment "ROM2"                 ; Switch to ROM2 segment
>             .segment "ZP2": zeropage        ; New direct segment
>             .segment "ZP2"                  ; Ok, will use last attribute
>             .segment "ZP2": absolute        ; Error, redecl mismatch

> `

See: `.BSS`, `.CODE`, `.DATA` and `.RODATA`

## 11.88 `.SETCPU`

Switch the CPU instruction set. The command is followed by a string that specifies the CPU. Possible values are those that can also be supplied to the `--cpu` command line option, namely: 6502, 6502X, 65SC02, 65C02, 65816, sunplus and HuC6280. Please note that support for the sunplus CPU is not available in the freeware version, because the instruction set of the sunplus CPU is "proprietary and confidential".

See: `.CPU`, `.IFP02`, `.IFP816`, `.IFPC02`, `.IFPSC02`, `.P02`, `.P816`, `.PC02`, `.PSC02`

## 11.89 `.SMART`

Switch on or off smart mode. The command must be followed by a '+' or '-' character to switch the option on or off respectively. The default is off (that is, the assembler doesn't try to be smart), but this default may be changed by the -s switch on the command line.

In smart mode the assembler will do the following:

- Track usage of the `REP` and `SEP` instructions in 65816 mode and update the operand sizes accordingly. If the operand of such an instruction cannot be evaluated by the assembler (for example, because the operand is an imported symbol), a warning is issued. Beware: Since the assembler cannot trace the execution flow this may lead to false results in some cases. If in doubt, use the `.Inn` and `.Ann` instructions to tell the assembler about the current settings.
- In 65816 mode, replace a `RTS` instruction by `RTL` if it is used within a procedure declared as `far`, or if the procedure has no explicit address specification, but it is `far` because of the memory model used.

Example:

> `

>             .smart                          ; Be smart
>             .smart  -                       ; Stop being smart

> `

See: `.A16`, `.A8`, `.I16`, `.I8`

## 11.90 `.STRUCT`

Starts a struct definition. Structs are covered in a separate section named "Structs and unions".

See: `.ENDSTRUCT`

## 11.91 `.SUNPLUS`

Enable the SunPlus instructions set. This command will not work in the freeware version of the assembler, because the instruction set is "proprietary and confidential".

See: `.P02`, `.PSC02`, `.PC02`, and `.P816`

## 11.92 `.TAG`

Allocate space for a struct or union.

Example:

> `

>             .struct Point
>                     xcoord  .word
>                     ycoord  .word
>             .endstruct

>             .bss
>                     .tag    Point           ; Allocate 4 bytes

> `

## 11.93 `.WARNING`

Force an assembly warning. The assembler will output a warning message preceded by "User warning". This warning will always be output, even if other warnings are disabled with the `-W0` command line option.

This command may be used to output possible problems when assembling the source file.

Example:

> `

>             .macro  jne     target
>                     .local L1
>                     .ifndef target
>                     .warning "Forward jump in jne, cannot optimize!"
>                     beq     L1
>                     jmp     target
>             L1:
>                     .else
>                     ...
>                     .endif
>             .endmacro

> `

See also the `.ERROR` and `.OUT` directives.

## 11.94 `.WORD`

Define word sized data. Must be followed by a sequence of (word ranged, but not necessarily constant) expressions.

Example:

> `

>             .word   $0D00, $AF13, _Clear

> `

## 11.95 `.ZEROPAGE`

Switch to the ZEROPAGE segment and mark it as direct (zeropage) segment. The name of the ZEROPAGE segment is always "ZEROPAGE", so this is a shortcut for

> `

>             .segment  "ZEROPAGE", zeropage

> `

Because of the "zeropage" attribute, labels declared in this segment are addressed using direct addressing mode if possible. You must instruct the linker to place this segment somewhere in the address range 0..$FF otherwise you will get errors.

See: `.SEGMENT`

Next Previous Contents